Rebuild BPP by MINGW for 32bit and 64bit

2025-12-07T09:50:02.077000Z

Hello Han
I just stoped over BPP i almost forget avout it .
You say that you recompile it with fixed bugs
so ..may I ask is there recompiled version for download ?
thanks

wxWidgets GUI improvment

2020-02-20T06:15:11.436000Z

Option Explicit

using wxWidgets

Dim f As wxFrame
Dim m_treeCtrl As wxTreeCtrl

Sub OnItemSelectChanging(byref event As wxTreeEvent)
    Dim item As wxTreeItemId = event.GetItem()
    f.SetTitle( "treectrl demo " + m_treeCtrl.GetItemText( item ) )
End Sub

Sub Main

    f = new wxFrame( NULL, wxID_ANY, "treectrl demo" )

    Dim images As wxImageList ptr = new wxImageList(15, 15, true)   
    images.Add( wxICON(wxICON_SMALL_CLOSED_FOLDER) )
    images.Add( wxICON(wxICON_SMALL_OPEN_FOLDER) )
    images.Add( wxICON(wxICON_SMALL_FILE) )

    m_treeCtrl = new wxTreeCtrl(f, wxID_ANY, wxDefaultPosition, wxDefaultSize, wxTR_DEFAULT_STYLE)
    m_treeCtrl.SetImageList( images )

    Dim root As wxTreeItemId = m_treeCtrl.AppendItem( NULL, "root", 0, 1 )
    m_treeCtrl.AppendItem( root, "item1", 2 )
    m_treeCtrl.AppendItem( root, "item2", 2 )
    m_treeCtrl.AppendItem( root, "item3", 2 )
    m_treeCtrl.AppendItem( root, "item4", 2 )
    m_treeCtrl.AppendItem( root, "item5", 2 )

    m_treeCtrl.Bind( wxEVT_TREE_SEL_CHANGING, AddressOf OnItemSelectChanging )

    f.SetIcon( wxICON(wxICON_AAA) )
    f.Show(true)

End Sub

GUI with wxWidgets

2020-02-04T07:15:13.953000Z

Option Explicit
Option CONSOLE OFF

Sub OnItemSelected(ByRef ev as wxListEvent)
    wxMessageBox( ev.GetText() )
End Sub

Sub Main

    dim f as wxFrame ptr
    f = new wxFrame( NULL, wxID_ANY, "listctrl" )

    dim listctrl as wxListCtrl ptr = new wxListCtrl( f, wxID_ANY, wxDefaultPosition, wxDefaultSize, wxLC_REPORT )

    listctrl.InsertColumn(0, "spalte1")
    listctrl.InsertColumn(1, "spalte2")

    listctrl.InsertItem(0,"Eintrag 1")
    listctrl.InsertItem(1,"Eintrag 2")

    listctrl.SetItem(0,1,"Eintrag 3")
    listctrl.SetItem(1,1,"Eintrag 4")

    listctrl.Bind ( wxEVT_LIST_ITEM_SELECTED , AddressOf OnItemSelected )

    f.Show(true)
End Sub

For Each synax for ComObject

2019-12-26T07:00:00.935000Z

Option Explicit
Option CONSOLE OFF

Sub Main

    DIM Xlb As ComObject, Xls AS ComObject, xlapp AS ComObject

    xlapp.CreateObject("Excel.Application")
    xlapp.Visible = TRUE

    Xlb = xlapp.Workbooks.Add

    for each Xls in Xlb.WorkSheets
        msgbox Xls.Name
    next

    for each Xls2 as comobject in Xlb.WorkSheets
        msgbox Xls2.Name
    next

    xlapp.DisplayAlerts = FALSE
    msgbox "click to continue..."

    xlapp.quit

End Sub

CallByName function !!!Only for ComObject

2019-12-26T01:00:21.521000Z

Option Explicit
Option CONSOLE OFF

Sub Main

    DIM Xlb As ComObject, Xls AS ComObject, Rng AS ComObject,xlapp AS ComObject

    xlapp.CreateObject("Excel.Application")
    xlapp.Visible = TRUE

    Xlb = xlapp.Workbooks.Add
    Xls = Xlb.WorkSheets(1)

    dim sName as string
    sName = "Name"

    msgbox CallByName(xls, "Name")
    msgbox CallByName(xls, sName)

    Rng = CallByName(xls, "Range")("A1:A5")
    Rng.Font.Size = 14

    Rng = Xls.Range("A2:A5")
    Rng.Interior.ColorIndex = 36
    Rng.EntireColumn.Autofit

    xlapp.DisplayAlerts = FALSE
    msgbox "click to continue..."

    xlapp.quit

End Sub

TreeView sample

2019-12-25T04:01:17.326000Z

USING BApp
USING BForms
USING BTreeViews
USING BImageLists

Option Explicit
Option CONSOLE OFF

Dim App As New BApplication
Dim Form1 As New BForm
Dim Tree1 As New BTreeView
Dim imglist As New BSysImageList

Declare sub showdir(sDir as string, mask as string, hTreeParent As Long)

Private Sub Form1_DblClick(Button As Long)
    MsgBox "Form1 DoubleClick!"
End Sub

Private Sub Form1_OnSize(Button As Long)
    Tree1.Height = Form1.ClientHeight - 20
    Tree1.Width = Form1.ClientWidth - 20
End Sub

Private Sub Tree1_SelectChanged(Sender As Long, itemNew As Long, itemOld As Long)
    Form1.Caption = "SelectChanged: from " + Tree1.GetItemText(itemOld) + " to " + Tree1.GetItemText(itemNew)
End Sub

Private Sub Tree1_ItemExpanding(Sender As Long, item As Long)

    Dim hChild As Long

    With Tree1

        hChild = .GetChild( item )

        If .GetItemText(hChild) = ".." Then
            .DeleteItem( hChild )

            showdir( .GetPathText( item ),  "*.*", item )
        End If

    End With

End Sub

sub showdir'(sDir as string, mask as string, hTreeParent As Long)

    dim ss as string, path as string

    ss =  Dir(sDir + "\" + mask)

    if hTreeParent = 0 then
        hTreeParent = Tree1.AddItem( hTreeParent, sDir, imglist.GetIconIndex(sDir), imglist.GetIconIndexOpen(sDir) )
    end if

    do while ss <> ""

        path =  sDir + "\" + ss
        if ss <> "." and  ss <> ".." then

            Dim hItem As Long
            hItem = Tree1.AddItem( hTreeParent, ss, imglist.GetIconIndex(path), imglist.GetIconIndexOpen(path) )

            if GetAttr BAnd FileAttrDirectory then
                Tree1.AddItem( hItem, ".." )
            end if
        end if

        ss = dir
    loop
end sub

Sub Main

    App.Create

    Form1.OnDblClick = AddressOf Form1_DblClick
    Form1.OnReSize = AddressOf Form1_OnSize

    Form1.Caption = "B++ Test Application"
    Form1.Startup = True 'you must set startup to some form to correct program exit
    Form1.Style = wsSizable

    Form1.Create

    Tree1.Caption = "Tree1"
    Tree1.Parent = Form1.hWnd
    Tree1.Height = Form1.ClientHeight - 20
    Tree1.Width = Form1.ClientWidth - 20
    Tree1.Top = 10
    Tree1.Left = 10

    Tree1.OnSelectChanged = AddressOf Tree1_SelectChanged
    Tree1.OnItemExpanding = AddressOf Tree1_ItemExpanding

    Tree1.Create
    Tree1.SetImageList( imglist.hSmall )

    Call showdir("C:", "*.*", 0 )

    App.Run

    App.Destroy

End Sub

GUI sample 32bit and 64bit

2019-12-20T08:05:00.843000Z

Rebuild BPP by MINGW for 32bit and 64bit

2019-12-20T06:51:55.583000Z

using C++ codes directly

Function BCombo.WndProc

{{
if ( (WM_COMMAND) == uMsg ) {
if ( HIWORD(wParam) == CBN_SELCHANGE ) {
if ( OnSelectChanged > 0 ) {
}}

                RaiseEvent SelectChanged

{{
}
}
}
}}
Function = Super.WndProc(hWnd, uMsg, wParam, lParam)
End Function

Rebuild BPP by MINGW for 32bit and 64bit

2019-12-20T06:43:03.239000Z

Option Explicit
Option CONSOLE OFF

Sub Main

DIM Xlb As ComObject, Xls AS ComObject, Rng AS ComObject,xlapp AS ComObject

xlapp.CreateObject("Excel.Application")
xlapp.Visible = TRUE

Xlb = xlapp.Workbooks.Add
Xls = Xlb.WorkSheets(1)

with Xls.Cells(1, 1)
    .Value = "Name"

    with .Font
        .Bold = TRUE
        .ColorIndex = 2
    end with
    .Interior.ColorIndex = 30
    .Value = "Test value 1"
    .Value = "Test value 2"
    .Value = "Tets value 3"
    .Value = "Test value 4"
end with

Rng = Xls.Range("A1:A5")
Rng.Font.Size = 14

Rng = Xls.Range("A2:A5")
Rng.Interior.ColorIndex = 36
Rng.EntireColumn.Autofit

xlapp.DisplayAlerts = FALSE
msgbox "click to continue..."

xlapp.quit

End Sub

Rebuild BPP by MINGW for 32bit and 64bit

2019-12-20T06:37:20.463000Z

Option Explicit
Option CONSOLE OFF

Dim App As New BApplication
Dim Form1 As New BForm
Dim Tree1 As New BTreeView

Private Sub Form1_DblClick(Button As Long)
MsgBox "Form1 DoubleClick!"
End Sub

Private Sub SampleTreeView

Dim hRoot AS Long, hParent AS Long
Dim i AS Integer,j AS Integer, k AS Integer
Dim lCount As Integer = 5

FOR i = 1 TO lCount
    hRoot = Tree1.InsertItem(0, "Root"+ str(i) )
    FOR j = 1 TO lCount
        hParent = Tree1.InsertItem(hRoot, "Item"+ STR(j) )
        FOR k = 1 TO lCount
            Tree1.InsertItem(hParent, "SubItem"+ STR(j) + "." + STR(k)) 
        NEXT k
    NEXT j
NEXT i

End Sub

Sub Main

App.Create

Form1.OnDblClick = AddressOf Form1_DblClick

Form1.Caption = "B++ Test Application"
Form1.Startup = True 'you must set startup to some form to correct program exit
Form1.Style = wsSizable

Form1.Create

Tree1.Caption = "Tree1"
Tree1.Parent = Form1.hWnd
Tree1.Height = Form1.ClientHeight - 20
Tree1.Width = Form1.ClientWidth - 20
Tree1.Top = 10
Tree1.Left = 10

Tree1.Create

Call SampleTreeView

App.Run

App.Destroy

End Sub

Recent posts to Discussion

Rebuild BPP by MINGW for 32bit and 64bit

wxWidgets GUI improvment

GUI with wxWidgets

For Each synax for ComObject

CallByName function !!!Only for ComObject

TreeView sample

GUI sample 32bit and 64bit

Rebuild BPP by MINGW for 32bit and 64bit

Rebuild BPP by MINGW for 32bit and 64bit

Rebuild BPP by MINGW for 32bit and 64bit